***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 06, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJC7410 drain  gate  source
rg     gate    1t    1
m1      2    1    3    3    dmos    L=1u   W=1u
.model dmos nmos ( 
+vto = {0.738*((8e-3*(temp-25))+1)}
+kp = {2.805*((3e-2*(temp-25))+1)}
+theta = 0.2  
+tnom = 25
+vmax = 0 
+level = 3)   
cgs	1t	3	50p	ic = 0
rd	drain	4	0.001	tc=0.08
dds	3	4	dds
gds  drain  source  value = {0.0043*(temp-25)*limit((v(gate, source)-0.72),0,2.5)*limit(v(drain,source),0,1)}
.model dds d (bv = 22  ibv = 0.25e-6  tbv1 = 5.5e-4  m=0.36  cjo=32p  vj=0.8)
e1	1 3 table { v(1t, source) } 
+ ((0, 0)
+  (1.00, 0.99)
+  (1.25, 1.28)
+  (1.50, 1.52)
+  (1.75, 1.72)
+  (2.00, 1.88)
+  (2.50, 2.12)
+  (3.00, 2.30)
+  (3.50, 2.50)
+  (5.00, 2.52)) 
dbody   3   drain    dbody
.model   dbody    d(
+is = 8e-7
+ n = 2.093	
+rs = {0.264*(1-0.98*(temp-25))}	
+tt = 100n	
+vj = 0.8	
+eg = 0.85 )
ra      4    2    0.02  tc=0.08
rs      3    5    1e-3
ls      5    source   0.0001n
m2      1t    8    6    6   inter
e2      8    6    4    1t   2
.model	inter	nmos(vto=0	kp=10	level=1) 
cgdmax  7    4    10p ic=0
rcgd    7    4    10meg
dgd     6    4    dgd
rdgd    4    6    10meg
.model     dgd    d(m=0.3   cjo=68p   vj=0.4)
m3      7    9    1t    1t   inter
e3      9    1t    4    1   -2
.ends
*$
